comment:
This is an IPAT-S script. IPAT-S is an open-source scripting language
for developing sustainability scenarios. It can be run using the free
IPAT-S software, available from:

	http://ipat-s.kb-creative.net/

For more information, please contact the author of IPAT-S,
Eric Kemp-Benedict (eric@kb-creative.net)
:comment

comment:
This script implements the "ImPACT" formula of Waggoner and
Ausubel. ImPACT is an extension of the original "IPAT"
formula that explicitly takes consumption patterns into
account.
:comment

baseyear 2000
scenyears 2010 to 2050 by 10

# There are many ways to implement the ImPACT formula: see the
# discussion on the IPAT-S site (http://www.kb-creative.net/IPAT_S).
# In this implementation, population P and impact Im are summable
summvar P Im
# while "affluence" A, consumption C and technology T are expressed as
# growth rates
ratio A C T

P.0 = 283	# million people
Im.0 = 100	# Impact set arbitrarily at 100 in base year

ratio p = growth(<1.0%>) 	# Annual population growth
:: >> p -> P

A = growth(<2.0%>) 		# Income growth rate
C = growth(<-1.5%>)		# Dematerialization
T = growth(<-2.5%>)		# Efficiency improvements

###########################################################
##
## The ImPACT formula:
##
#   - Population drives changes in impact
#   - Modified by income, dematerialization and technology

::	P >> A * C * T -> Im

###########################################################

# As a final step, suppose that initial GDP is known. Then
# absolute levels of GDP and consumption can be calculated
# using the script parameters.
summvar GDP, Consumption
GDP.0 = 25000 * P.0
:: P >> A -> GDP
Consumption.0 = 83% * GDP.0
:: GDP >> C -> Consumption


report P as "Population (millions)"
report GDP/P as "Income ($/cap)"
report 100 * Consumption/GDP as "Consumption Share (%)"
report 100 * (Im/Consumption)/(Im/Consumption).0 as "Technology (2000 = 100)"
report Im as "Impact (2000 = 100)"